[VB.NET] Disegnare un rettangolo

[Bizkaiko]

Ciao,
sto provando a creare un'applicazione in vb.net tipo il Paint di Windows, però non so come riuscire a creare un rettangolo.
O meglio: per crearlo uso il drawRectangle, memorizzandomi il punto inziale sull'evento MouseDown e quello finale sul MouseUp.
Però vorrei fare in modo che mentre trascino il mouse sulla picturebox mi si veda un'anteprima di quello che andrà a creare, ma non ho idea di come fare...

[||ElChE||88]

Usa l'evento MouseMove per aggiornare la preview.

[Bizkaiko]

Ci avevo già pensato, però come faccio io non funziona.
Praticamente ho 2 routine, una che mi copia in memoria l'immagine iniziale che c'è in PaintBox1, e l'altra che me la ricarica a video:

Private Sub SalvaImmagineTEMP()
TempBMP = New Drawing.Bitmap(PictureBox1.Width, PictureBox1.Height)
PictureBox1.DrawToBitmap(TempBMP, New Rectangle(0, 0, TempBMP.Width, TempBMP.Height))
Exit Sub

Private Sub IncollaImmagineTEMP()
Dim bm As Bitmap = TempBMP 
Dim bm_dest As New Bitmap(bm.Width, bm.Height)
Dim gr_dest As Graphics = Graphics.FromImage(bm_dest)
gr_dest.DrawImage(bm, 0, 0, bm_dest.Width + 1, bm_dest.Height + 1)
g = Graphics.FromImage(bm)
PictureBox1.Image = bm
Exit Sub

Poi negli eventi relativi al paintbox:
MouseDown:
-qui chiamo la procedura SalvaImmagineTEMP e memorizzo le coordinate del punto di partenza

Mousemove:
-faccio partire la IncollaImmagineTEMP in modo da riportarmi all'immagine iniziale, poi memorizzo il punto in cui mi trovo e lancio un drawRectangle

MouseUp
-chiamo ancora la IncollaImmagineTEMP e poi disegno il rettangolo definitivo.

Però continuo a non visualizzare nulla mentre trascino il mouse, invece quando lo rilascio mi disegna il rettangolo desiderato, più una serie di rettangoli "intermedi" che mi sarebbero serviti prima...

[MarcoGG]

Non è tanto disegnare il rettangolo in sè, il problema, quanto il fatto che dare il Refresh sul Control dove si disegna, implica la cancellazione degli eventuali rettangoli già presenti.
In breve, una buona soluzione al problema è di separare il disegno corrente dai disegni già presenti sul controllo. Quando si stacca il mouse ( MouseUp ) creo un oggetto "Rettangolo", e lo aggiungo ad una collection. Quando disegno ( MouseMove ), oltre a refreshare il Control per liberarmi delle "tracce intermedie" del disegno, vado a ridisegnare i rettangoli precedenti.

Nel mio esempio disegno rettangoli su una PictureBox ( "PCB" ) :

Public Class Form1

    Private P As New Pen(Color.Green, 2)
    Private R As Rettangolo
    Private rect As Rectangle
    Private rettangoli As New List(Of Rettangolo)

    Private inDisegno As Boolean = False
    Private xStart As Integer = 0
    Private yStart As Integer = 0
    Private xEnd As Integer = 0
    Private yEnd As Integer = 0

    Private Class Rettangolo
        Public Rct As Rectangle
        Public Pn As Pen
        Public Sub New(ByVal P As Pen, ByVal R As Rectangle)
            Pn = P
            Rct = R
        End Sub
    End Class

    Private Sub RiDisegna()

        PCB.Refresh()
        PCB.CreateGraphics.DrawRectangle(P, rect)
        For Each R As Rettangolo In rettangoli
            PCB.CreateGraphics.DrawRectangle(R.Pn, R.Rct)
        Next

    End Sub

    Private Sub PCB_MouseDown(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles PCB.MouseDown

        PCB.Cursor = Cursors.Cross
        inDisegno = True
        xStart = e.X
        yStart = e.Y

    End Sub

    Private Sub PCB_MouseMove(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles PCB.MouseMove

        If inDisegno = False Then Exit Sub

        xEnd = e.X
        yEnd = e.Y
        rect = New Rectangle
        If xStart < xEnd Then
            rect.X = xStart
        Else
            rect.X = xEnd
        End If
        If yStart < yEnd Then
            rect.Y = yStart
        Else
            rect.Y = yEnd
        End If
        rect.Width = Math.Abs(xEnd - xStart)
        rect.Height = Math.Abs(yEnd - yStart)

        RiDisegna()

    End Sub

    Private Sub PCB_MouseUp(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles PCB.MouseUp

        PCB.Cursor = Cursors.Arrow
        inDisegno = False
        R = New Rettangolo(P, rect)
        rettangoli.Add(R)

    End Sub

End Class

[Bizkaiko]

Grazie mille!!!
Adesso provo a sfruttare il codice per creare qualcosa di simile anche con un'immagine di sfondo ed altre figure!

[Bizkaiko]

Ok, con la soluzione che mi hai suggerito riesco a gestire 1 immagine jpeg/gif... e le varie figure geometriche senza problemi.

L'unica cosa che non riesco a gestire è il disegno a mano libera.
Avevo pensato di provare a generare un rettangolo per ogni punto che vado a toccare col mouse, o una serie di linee dal punto1-->punto2-->punto3 ecc, però non funziona.
Hai qualche suggerimento ancora?
Grazie mille!

[Bizkaiko]

Come non detto, noon avevo inserito una verifica che il punto iniziale non coincidesse con quello finale, altrimenti non mi generava nessuna linea!

[MarcoGG]

E' chiaro che più vai avanti, più le cose diventeranno complicate. Questa tecnica può essere buona per disegni che contengono un numero "ragionevole" di forme, e sulle quali, una volta disegnate, non si prevede più di intervenire.
Se vuoi creare forme via via più complesse, considera anche l'ipotesi di fare il tutto in modo "vettoriale", non più disegnando direttamente sul Control di sfondo, ma creando veri e propri controlli personalizzati ( e quindi classi ), ciascuno dei quali ha al suo interno tutte le regole necessarie per il disegno, il ridimensionamento, lo spostamento, ecc...
Qui trovi un mio spunto :
http://www.hwupgrade.it/forum/showthread.php?t=2053119