[Visual Basic] Terminare un processo

[Swisström]

come faccio a terminare un processo di windows con visual basic?

io so solo il nome di quel processo e non l'ID

il processo non ha finestre aperte

[Swisström]

up

io ho visot che si possono enumerare tutti i processi... potrei farli enumerare e poi cercare all'interno di un array (o simili metodi) quello con nome XXX.exe (siccome non si può avere l'id dal nome ma si puo avere il nome dall'ID) e dopo killarlo con un normalissimo TerminateProcess()


che ne dite? nessuno mi mette giù una bozza di codice? che se devo farlo io ci butto via una giornata

[Swisström]

ok scherzavo c'ho messo 5 minuti

ora lo testo, lo metto a posto e poi lo metot qui sul forum

[71104]

io te lo posso scrivere in C, e magari dopo cena va, che mo non c'ho tempo
comunque si, devi fare così come hai detto; per enumerare i processi esiste un'infinità di maniere: PSAPI, Toolhelp, WMI, NtQuerySystemInformation... (quest'ultima solo su sistemi NT)
io in genere uso le Toolhelp che sono le più portabili di tutte, infatti si trovano in kernel32.dll

[71104]

mi hai preceduto

[Swisström]

questo è copiato di pari passo da un sito...
ne avevo fatto uno ma usciva meno bene e allora mi son dato al copy and paste

Option Explicit
'on win2k you need the following:
Private Const PROCESS_TERMINATE = &H1
'On nt 9X the following could be enough:
Private Const PROCESS_ALL_ACCESS = &H1F0FFF
'in any case, let us use both...
Private Const MAX_PATH As Integer = 260

Private Type PROCESSENTRY32
  dwSize As Long
  cntUsage As Long
  th32ProcessID As Long
  th32DefaultHeapID As Long
  th32moduleID As Long
  cntThreads As Long
  th32ParentProcessID As Long
  pcPriClassBase As Long
  dwFlags As Long
  szExeFile As String * MAX_PATH
End Type

Private Declare Function CreateToolHelpSnapshot Lib "kernel32" Alias "CreateToolhelp32Snapshot" (ByVal lFlags As Long, ByVal lProcessID As Long) As Long
Private Declare Function ProcessFirst Lib "kernel32" Alias "Process32First" (ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Private Declare Function ProcessNext Lib "kernel32" Alias "Process32Next" (ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Private Declare Function TerminateProcess Lib "kernel32" (ByVal ApphProcess As Long, ByVal uExitCode As Long) As Long
Private Declare Function OpenProcess Lib "kernel32" (ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, ByVal dwProcessId As Long) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long

Public Function KillApp(myName As String) As Boolean
    Dim uProcess As PROCESSENTRY32
    Dim rProcessFound As Long
    Dim hSnapShot As Long
    Dim szExename As String
    Dim exitCode As Long
    Dim myProcess As Long
    Dim iFound As Integer
        On Error GoTo ErrHandler
    
    Const TH32CS_SNAPPROCESS As Long = 2&
        uProcess.dwSize = Len(uProcess)
    hSnapShot = CreateToolHelpSnapshot(TH32CS_SNAPPROCESS, 0&)
    rProcessFound = ProcessFirst(hSnapShot, uProcess)
    
    Do While rProcessFound
       iFound = InStr(1, uProcess.szExeFile, Chr(0)) - 1
       If iFound > 0 Then
           szExename = LCase$(Left$(uProcess.szExeFile, iFound))
        
           If Right$(szExename, Len(myName)) = LCase$(myName) Then
                              myProcess = OpenProcess(PROCESS_ALL_ACCESS Or PROCESS_TERMINATE, False, uProcess.th32ProcessID)
               KillApp = TerminateProcess(myProcess, exitCode)
               Call CloseHandle(myProcess)
               Exit Do
           End If
           rProcessFound = ProcessNext(hSnapShot, uProcess)
       End If
    Loop
    Call CloseHandle(hSnapShot)
    Exit Function
ErrHandler:
    MsgBox Err.Description
End Function

però ho un problemuccio... quando killo explorer.exe mi si riapre (winxp prof) subito dopo... ora ho mesos un timer però l'applicazione diventa più pesante...

[fgmac]

explorer.exe e' il programma principale di windows, quello che tiene su il desktop (nell'accezione + generale). Se lo termini da task manager per poter continuare a lavorare col pc devi ricaricartelo a manina dal task manager. Probabilmente c'e' un meccanismo di recovery per quando explorer cade per errore (tu vai ad inserirti in questo caso).

ciao,