[vba excel] memorizzare alcune celle di di intervallo di selezione

[john_revelator]

Ciao a tutti. Vi spiego rapidamente la mia necessità.
A questo indirizzo potete vedere un'immagine utile a spiegare il mio problema.

http://img265.imageshack.us/my.php?image=excelch6.png

Praticamente devo creare una macro che consenta di selezionare un intervallo di celle. Nell'immagine postata l'intervallo potrebbe essere a1:af15 oppure a17:af31 e così via. A partire da questo intervallo che l'utente selezionerà dovrò inserire in un altro foglio una serie di dati.
Mi chiedevo se fosse possibile una volta selezionato un range di celle copiarne solo una parte in un altro foglio. Nello specifico dovrei copiare la parte relativa ai giorni. Quindi se venisse selezionato l'intervallo a1:af15 allora dovrei poter copiare il range c1:af3, se venisse selezionato l'intervallo a17:af31 dovrei poter copiare l'intervallo c17:af19. Spero di essere stato chiaro.

[MarcoGG]

Originariamente inviato da john_revelator

...
A partire da questo intervallo che l'utente selezionerà dovrò inserire in un altro foglio una serie di dati.
Mi chiedevo se fosse possibile una volta selezionato un range di celle copiarne solo una parte in un altro foglio. Nello specifico dovrei copiare la parte relativa ai giorni. Quindi se venisse selezionato l'intervallo a1:af15 allora dovrei poter copiare il range c1:af3, se venisse selezionato l'intervallo a17:af31 dovrei poter copiare l'intervallo c17:af19. Spero di essere stato chiaro.

Vediamo un po'... Vuoi che una certa operazione di copia/incolla di un range da un foglio all'altro venga eseguita via codice ?
Questo è semplice, solo non ho capito quale dev'essere l'evento scatenante : l'utente seleziona un range "a mano", Excel se ne accorge e copia un sub-range del range selezionato in un altro foglio ?

[john_revelator]

Ciao Marco.
Hai colto perfettamente il problema. In pratica l'utente tramite una finestra selezionerà l'intervallo su cui dovranno essere elaborate una serie di operazioni. All'interno di questo intervallo una parte di esso deve essere copiato in un altro foglio. Almeno questro problema credo di averlo risolto. Infatti sapendo a priori l'intervallo di colonne che dovrà essere selezionato è sufficiente che ricavi la prima riga selezionata e aggiunga 2 a tale valore per selezionare l'ultima riga che mi serve.

Sub selezione()
Set rng = Application.InputBox(Prompt:="Selezione intervallo", Title:="Scelta intervallo", Type:=8)
rng.Select
primariga = selection.Row
ActiveSheet.Range("c" & primariga & ":af" & primariga + 2).Select
selection.Copy
ThisWorkbook.Sheets("frontale").Activate
ActiveSheet.Range("g32").Select
ActiveSheet.Paste
End Sub

Domani proverò a risolvere il problema principale di ciò che dovrei fare. Temo che dovrò tornare a chiedere il tuo aiuto ma priva voglio almeno provarci da solo. Grazie come sempre per la tua gentilezza.

[MarcoGG]

Giusto, vai così !
Anch'io prima di chiedere aiuto a qualcuno... ...

[john_revelator]

E' tutto il giorno che ma non vengo a capo di nulla.

In questa immagine potete vedere il file come dovrebbe essere generato tramite vba

2) http://www.picoodle.com/view.php?img....png&srv=img32

a partire dal foglio di cui ho postato l'immagine in precedenza

1) http://img265.imageshack.us/my.php?image=excelch6.png

Supponiamo che selezioni l'intervallo 12-17 maggio (1) All'interno di queste colonne (5 per ciascun giorno relative alle varie ore) c'è un numero corrispondente all'ora durante la quale l'aula (riportata nella prima colonna a sinistra) sarà occupata. Nel secondo foglio dovrei creare una riga relativa a ciascun corso che impegnerà almeno un'aula durante la settimana in questione. In pratica nel calendario del primo foglio è riportato il numero del corso su ogni singola cella, mentre nel secondo dovrei riportare l'aula.

Pensavo di ciclare tutto il "calendario", inserire i numeri in un array. Estrarre i valori senza duplicati e creare una riga per ogni singolo corso. Ho però la sensazione che il mio approccio sia sbagliato e anche se riuscissi a fare questo non saprei come riportare il nome dell'aula (A,b,C, ecc.) all'interno delle celle al posto del numero del corso. Spero di essere stato chiaro e possiate almeno darmi una qualche indicazione.
Grazie a tutti.

[MarcoGG]

Originariamente inviato da john_revelator

Supponiamo che selezioni l'intervallo 12-17 maggio (1) All'interno di queste colonne (5 per ciascun giorno relative alle varie ore) c'è un numero corrispondente all'ora durante la quale l'aula (riportata nella prima colonna a sinistra) sarà occupata. Nel secondo foglio dovrei creare una riga relativa a ciascun corso che impegnerà almeno un'aula durante la settimana in questione. In pratica nel calendario del primo foglio è riportato il numero del corso su ogni singola cella, mentre nel secondo dovrei riportare l'aula.

Bel casino, niente male davvero .
Allora :
- Le ore di mattina / pomeriggio sono sempre 5 ? In pratica se l'ora 1 di un pomeriggio è occupata significa che quell'ora è 14:30>>15:30. Giusto ?
Però non mi spiego tanto quel 14:45>>19:45, che a quanto pare vale solo per il "23"...

- Quei numeri dal 7 al 33 sono una specie di codice-corso ?

- Così su 2 piedi, non nascondo che avrei strutturato i fogli in modo diverso, ma qui dipende molto da come si vuole realizzare il tutto.
In ogni caso hai pensato di usare per ogni cella un Type ( variabile customizzata ) personalizzato ?

Una cosa del genere :

Public Type cellaOraria
    codiceCorso As String '7,17,18 ecc.
    aula As String 'A,B,C ecc.
    matPom As String 'M se mattino / P se pomeriggio
    numOra As Integer '1,2,3,4,5
    giorno As Integer 'da 1 a 31
    mese As Integer 'da 1 a 12
End Type

In pratica sul foglio1 crei una variabile di questo tipo per ogni cella del range interessato ( ogni "proprietà" di questo Type andrà calcolata opportunamente derivandola dalle sue coordinate - Esempio : se l'indice di riga è dispari >> è un'ora pomeridiana, e così via... ).
Poi metti tutti questi Types in un array >> Scorri l'array per generare le righe del foglio2... Un bello sbattimento insomma, ma fattibile...

[john_revelator]

Ciao Marco. Allora i numeri 7,33, ecc. fanno esattamente riferimento ad un codice univoco assegnato a ciascun corso. Il fatto del 14.45-19.45 non è un problema. Al limite si modifica a mano. Evidentemente è un corso che inizia con un quarto d'ora di ritardo. (Il problema che ho posto non è mio. Sto cercando di fare un favore a un amico che però non è capitato in buone mani .

Stasera a casa mi studio il codice che hai postato. Sono completamente digiuno di variabili customizzate.

Se comunque hai un'idea di struttura più semplice per arrivare alla generazione automatica del foglio "frontale" ogni consiglio è ben accetto.
Grazie ancora.

[MarcoGG]

Originariamente inviato da john_revelator

Se comunque hai un'idea di struttura più semplice per arrivare alla generazione automatica del foglio "frontale" ogni consiglio è ben accetto.
Grazie ancora.

Io penserei ad una tabella mensile per ogni foglio, facile e veloce da realizzare, e da analizzare per via programmatica, come questa :



- Su [I4] faccio un bel Menu/Finestra/Blocca Riquadri, in modo da rendere scorrevole la tabella oraria e non perdere il riferimento con le aule.
La riga 1 è libera per l'inserimento di eventuali pulsanti che così rimangono sempre in primo piano.

- La tabella si genera velocemente : basta creare il primo giorno del mese, poi trascinare in basso la grande cella quadrata con il giorno [A4] per generare tutte le altre. Per il Range [B4:H13] basta trascinare in basso premendo CTRL per non incrementare M1, M2 ecc...

- A questo punto con VBA posso risalire agli attributi ( giorno, corso, mattina, pomeriggio, aula ) di ogni cella nel Range[A4:H*] semplicemente derivandoli dalle sue coordinate, popolare il mio Array di variabili (Types) customizzate, e infine non dovrebbe essere difficile generare qualsivoglia foglio secondario.

[MarcoGG]

Vedo che ci stai pensando...
Per dovere di completezza "concludo" illustrando come gestirei i miei Types usando la mia struttura fogli, con questo esempio :

1. In un modulo definisco il mio Type :

Public Type cellaOraria
    codiceCorso As String '7,17,18 ecc.
    aula As String 'A,B,C ecc.
    matPom As String 'M se mattino / P se pomeriggio
    numOra As Integer '1,2,3,4,5
    data As String
End Type

2. Al Click di un pulsante sul Foglio di Maggio ciclo tutte le celle dell'intervallo interessato e creo altrettanti Types cellaOraria, derivando le proprietà di ciascuno dalle sue coordinate :

Private Sub CommandButton1_Click()

    'Assegnamento Types nel Range di Test [ G19:H20 ] :
    
    Dim cella As Range
    For Each cella In Range("G19:H20")
        
        Dim questaCella As cellaOraria
        Dim questaCellaRow As Integer
        questaCellaRow = 0
        
        questaCella.aula = Cells(3, cella.Column).Text
        
        questaCella.codiceCorso = cella.Value
        
        questaCella.matPom = Left(Cells(cella.Row, 2).Text, 1)
        
        questaCella.numOra = Right(Cells(cella.Row, 2).Text, 1)
        
        questaCellaRow = cella.Row
        If CInt(Right(CStr(questaCellaRow), 1)) = 4 Then
            questaCella.data = Cells(questaCellaRow, 1).Text
        Else
            Dim i As Integer
            i = 0
            For i = questaCellaRow To (questaCellaRow - 10) Step -1
                If CInt(Right(CStr(i), 1)) = 4 Then
                    questaCella.data = Cells(i, 1).Text
                    Exit For
                End If
            Next i
        End If
            
        Dim strMsg As String
        strMsg = ".aula = " & questaCella.aula & vbCrLf & _
                 ".codiceCorso = " & questaCella.codiceCorso & vbCrLf & _
                 ".matPom = " & questaCella.matPom & vbCrLf & _
                 ".numOra = " & questaCella.numOra & vbCrLf & _
                 ".data = " & questaCella.data
                 
        MsgBox strMsg, vbInformation, "OK."
        
    Next

End Sub

Tempo impiegato : 5 min. più o meno...
Nello stesso For Each si potrà inserire il codice che aggiunge all'Array dei Types quello appena creato. E poi a ciclo concluso, con l'Array popolato si va dove si vuole...

[john_revelator]

Ciao Marco. Perdona la mia cafonaggine. Questi giorni sono stato un pò impegnato e non ho avuto ancora il tempo di esaminare tutto ciò che avevi già fatto. Mi ero ripromesso proprio stasera di metterci mano e postare. Questo pomeriggio testo tutto quello che hai fatto per me. Per adesso grazie mille come al solito e scusami ancora.

[MarcoGG]

Originariamente inviato da john_revelator

Ciao Marco. Perdona la mia cafonaggine. Questi giorni sono stato un pò impegnato e non ho avuto ancora il tempo di esaminare tutto ciò che avevi già fatto. Mi ero ripromesso proprio stasera di metterci mano e postare. Questo pomeriggio testo tutto quello che hai fatto per me. Per adesso grazie mille come al solito e scusami ancora.

No hay problema, fammi sapere...

[john_revelator]

Ciao Marco. E' dall'altro giorno che continuo a rileggermi il tuo codice. Ovviamente funziona perfettamente ma non ho la minima idea di come fare a integrare tutte le informazioni relative a ogni singola cella in un array (suppongo ) per poi poter generare un prospetto come questo

http://www.picoodle.com/view.php?img....png&srv=img32

in pratica due prospetti identici, uno relativo ai corsi mattinieri della settimana e uno a quelli pomeridiani

Immagino che una volta messo tutto in un array dovrei ricavare i valori unici relativi ai corsi per creare una riga per ciascun corso con tutte le informazioni ma non ho la minima idea di come fare.

[MarcoGG]

Intanto arriviamo ad avere l'Array definito e popolato con tutti i nostri Types :

1. L'Array deve essere pubblico, in modo da essere visto da ogni punto del progetto, perciò in un modulo ( lo stesso in cui ho definito il Public Type cellaOraria... ) :

Public arrayCelleOrarie() As cellaOraria

2. E questo è il codice di prima, con l'aggiunta e il test dell'Array :

Private Sub CommandButton1_Click()

    'Assegnamento Types nel Range di Test [ G19:H20 ] :
    
    Dim k As Integer
    k = 0
    Dim cella As Range
    For Each cella In Range("G19:H20")
        
        Dim questaCella As cellaOraria
        Dim questaCellaRow As Integer
        questaCellaRow = 0
        
        questaCella.aula = Cells(3, cella.Column).Text
        
        questaCella.codiceCorso = cella.Value
        
        questaCella.matPom = Left(Cells(cella.Row, 2).Text, 1)
        
        questaCella.numOra = Right(Cells(cella.Row, 2).Text, 1)
        
        questaCellaRow = cella.Row
        If CInt(Right(CStr(questaCellaRow), 1)) = 4 Then
            questaCella.data = Cells(questaCellaRow, 1).Text
        Else
            Dim i As Integer
            i = 0
            For i = questaCellaRow To (questaCellaRow - 10) Step -1
                If CInt(Right(CStr(i), 1)) = 4 Then
                    questaCella.data = Cells(i, 1).Text
                    Exit For
                End If
            Next i
        End If
            
        'Aggiungo il nuovo Type all'Array :
        ReDim Preserve arrayCelleOrarie(k + 1)
        arrayCelleOrarie(k) = questaCella
        k = k + 1
        
    Next
    
    'Verifica Array :
    Dim j As Integer
    For j = 0 To k - 1
   
        Dim strMsg As String
        strMsg = ".aula = " & arrayCelleOrarie(j).aula & vbCrLf & _
                 ".codiceCorso = " & arrayCelleOrarie(j).codiceCorso & vbCrLf & _
                 ".matPom = " & arrayCelleOrarie(j).matPom & vbCrLf & _
                 ".numOra = " & arrayCelleOrarie(j).numOra & vbCrLf & _
                 ".data = " & arrayCelleOrarie(j).data
                 
        MsgBox strMsg, vbInformation, "OK."
    
    Next j
    
End Sub

A questo punto l'Array è popolato e pronto all'uso...