[VB] lenght e altro

[djcuca]

raga allora..
se io ho un nome : GIANLUCA
voglio che l'indice i cicli dalla prima all'ultima lettera..
mi serve sapere come gli si dice lenght qualkosa del genere per dirgli
For i=1 to lunghezzadigianluca do...
capito?
appena risolviamo questo vi chiedo altro grazia!

[lalli83]

non sono sicura di avere capito quello che ti serve ma ci provo...

Len("gianluca")

è questo che ti serve?

[djcuca]

allora..
mi serve per controllare una textbox di email
e deve controllare appunto il testo inserito. e se non trova la @ devo far uscire un msgbox...

capito?

ho pensato il ciclo for ma basta?

[lalli83]

se devi solo cercare un carattere all interno della stringa non ti conviene fare un for ma usare la funzione InStr

cmq se vuoi io avevo fatto tempo fa un controllo completo x la correttezza di una mail...sarebbe da rivedere ma se lo vuoi te lo passo

[matpez]

Guarda se vuoi il controllo diretto te lo passo:

Public Function IsEmail(ByVal sEmail As String) As Boolean
  
  'controllo per verificare se una email è corretta formalmente
  
  Dim bOK             As Boolean
  Dim bSpecialChr     As Boolean
  Dim bErrore         As Boolean
  Dim nAt             As Integer
  Dim nI              As Integer
  Dim sUser           As String
  Dim sDominio        As String
  Dim sVetAux()       As String
  Dim nLen            As Integer
  
  
  bOK = False
  If sEmail <> "" And InStr(1, sEmail, "@") > 0 And InStr(1, sEmail, ".") > 0 Then
    nAt = 0
    bSpecialChr = False
    nLen = Len(sEmail)
    For nI = 1 To nLen
      'conto il numero di @ presenti nella stringa
      If Mid$(sEmail, nI, 1) = "@" Then nAt = nAt + 1
      'controllo carartteri speciali
      If Mid$(sEmail, nI, 1) >= Chr$(32) And Mid$(sEmail, nI, 1) <= Chr$(44) Then bSpecialChr = True
      If Mid$(sEmail, nI, 1) = Chr$(47) Or Mid$(sEmail, nI, 1) = Chr$(96) Or Mid$(sEmail, nI, 1) >= Chr$(123) Then bSpecialChr = True
      If Mid$(sEmail, nI, 1) >= Chr$(58) And Mid$(sEmail, nI, 1) <= Chr$(63) Then bSpecialChr = True
      If Mid$(sEmail, nI, 1) >= Chr$(91) And Mid$(sEmail, nI, 1) <= Chr$(94) Then bSpecialChr = True
    Next

    'se nella ricerca nn ci sono caratteri scpeciali e c''è una @ sola proseguo
    If nAt = 1 And bSpecialChr = False Then
      bErrore = False
      'splitto la stringa in due a livello della @
      sVetAux = Split(sEmail, "@")
      sUser = sVetAux(0)
      sDominio = sVetAux(1)
      If (sUser = "") Or (sDominio = "") Then bErrore = True
      If Mid$(sDominio, 1, 1) = "." Then bErrore = True
      If Mid$(sDominio, Len(sDominio), 1) = "." Then bErrore = True
      If Len(sDominio) - InStrRev(sDominio, ".") < 2 Then bErrore = True
      bOK = True
    End If
  End If

  If bErrore = True Then bOK = False

  IsEmail = bOK

End Function

Tanto lalli ti passava lo stesso

PS: consiglio...

Non fare mai un ciclo for di questo tipo...
For nI=1 to Len("ciao") perchè rallenti il ciclo, utlizza una variabile:

Dim nLen=Len("ciao")
For nI=1 to nLen

[lalli83]

[djcuca]

mi serve usare il TIME...
voglio che quando sia un orario da me impostato si spenga il pc..
per spegnere il pc devo usare la shell verO?penso di riuscirci..
cmq solo il fatto dell'orologio come si usa?

[matpez]

Per usare l'orologio è molto semplice...ci sono le seguenti funzioni:

Date: torna la data odierna (02/02/2004)
Time: torna l'ora del sistema operativo (14.31.41)
Now: torna entrambe (02/02/2004 14.31.41)

Per spegnere il pc nn è così semplice come sembra..ti posto un esempio...(non è il mio perchè se no mi dimentico sicuramente qlc cosa da mettere, per cui ti posto questo che fa la stessa cosa):

'In a module
Private Const EWX_LOGOFF = 0
Private Const EWX_SHUTDOWN = 1
Private Const EWX_REBOOT = 2
Private Const EWX_FORCE = 4
Private Const TOKEN_ADJUST_PRIVILEGES = &H20
Private Const TOKEN_QUERY = &H8
Private Const SE_PRIVILEGE_ENABLED = &H2
Private Const ANYSIZE_ARRAY = 1
Private Const VER_PLATFORM_WIN32_NT = 2
Type OSVERSIONINFO
    dwOSVersionInfoSize As Long
    dwMajorVersion As Long
    dwMinorVersion As Long
    dwBuildNumber As Long
    dwPlatformId As Long
    szCSDVersion As String * 128
End Type
Type LUID
    LowPart As Long
    HighPart As Long
End Type
Type LUID_AND_ATTRIBUTES
    pLuid As LUID
    Attributes As Long
End Type
Type TOKEN_PRIVILEGES
    PrivilegeCount As Long
    Privileges(ANYSIZE_ARRAY) As LUID_AND_ATTRIBUTES
End Type
Private Declare Function GetCurrentProcess Lib "kernel32" () As Long
Private Declare Function OpenProcessToken Lib "advapi32" (ByVal ProcessHandle As Long, ByVal DesiredAccess As Long, TokenHandle As Long) As Long
Private Declare Function LookupPrivilegeValue Lib "advapi32" Alias "LookupPrivilegeValueA" (ByVal lpSystemName As String, ByVal lpName As String, lpLuid As LUID) As Long
Private Declare Function AdjustTokenPrivileges Lib "advapi32" (ByVal TokenHandle As Long, ByVal DisableAllPrivileges As Long, NewState As TOKEN_PRIVILEGES, ByVal BufferLength As Long, PreviousState As TOKEN_PRIVILEGES, ReturnLength As Long) As Long
Private Declare Function ExitWindowsEx Lib "user32" (ByVal uFlags As Long, ByVal dwReserved As Long) As Long
Private Declare Function GetVersionEx Lib "kernel32" Alias "GetVersionExA" (ByRef lpVersionInformation As OSVERSIONINFO) As Long
'Detect if the program is running under Windows NT
Public Function IsWinNT() As Boolean
    Dim myOS As OSVERSIONINFO
    myOS.dwOSVersionInfoSize = Len(myOS)
    GetVersionEx myOS
    IsWinNT = (myOS.dwPlatformId = VER_PLATFORM_WIN32_NT)
End Function
'set the shut down privilege for the current application
Private Sub EnableShutDown()
    Dim hProc As Long
    Dim hToken As Long
    Dim mLUID As LUID
    Dim mPriv As TOKEN_PRIVILEGES
    Dim mNewPriv As TOKEN_PRIVILEGES
    hProc = GetCurrentProcess()
    OpenProcessToken hProc, TOKEN_ADJUST_PRIVILEGES + TOKEN_QUERY, hToken
    LookupPrivilegeValue "", "SeShutdownPrivilege", mLUID
    mPriv.PrivilegeCount = 1
    mPriv.Privileges(0).Attributes = SE_PRIVILEGE_ENABLED
    mPriv.Privileges(0).pLuid = mLUID
    ' enable shutdown privilege for the current application
    AdjustTokenPrivileges hToken, False, mPriv, 4 + (12 * mPriv.PrivilegeCount), mNewPriv, 4 + (12 * mNewPriv.PrivilegeCount)
End Sub
' Shut Down NT
Public Sub ShutDownNT(Force As Boolean)
    Dim ret As Long
    Dim Flags As Long
    Flags = EWX_SHUTDOWN
    If Force Then Flags = Flags + EWX_FORCE
    If IsWinNT Then EnableShutDown
    ExitWindowsEx Flags, 0
End Sub
'Restart NT
Public Sub RebootNT(Force As Boolean)
    Dim ret As Long
    Dim Flags As Long
    Flags = EWX_REBOOT
    If Force Then Flags = Flags + EWX_FORCE
    If IsWinNT Then EnableShutDown
    ExitWindowsEx Flags, 0
End Sub
'Log off the current user
Public Sub LogOffNT(Force As Boolean)
    Dim ret As Long
    Dim Flags As Long
    Flags = EWX_LOGOFF
    If Force Then Flags = Flags + EWX_FORCE
    ExitWindowsEx Flags, 0
End Sub

'In a form
'This project needs a form with three command buttons
Private Sub Command1_Click()
    LogOffNT True
End Sub
Private Sub Command2_Click()
    RebootNT True
End Sub
Private Sub Command3_Click()
    ShutDownNT True
End Sub
Private Sub Form_Load()
    'KPD-Team 2000
    'URL: http://www.allapi.net/
    'E-Mail: [email protected]
    Command1.Caption = "Log Off NT"
    Command2.Caption = "Reboot NT"
    Command3.Caption = "Shutdown NT"
End Sub