ebuild per beep media player

[GhePeU]

visto che ho perso un po' di tempo questa mattina ad adattare il vecchio ebuild posto anche qui, se qualcuno è interessato

beepmp-cvs-0.1.ebuild: scarica gli ultimi sorgenti disponibili nella cvs del progetto, oggi (31 maggio 2004) sembra funzionare bene, ma non è detto che succeda domani

beepmp-cvs-0.1.ebuild

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
 
inherit eutils cvs

MY_PN="bmp"
ECVS_SERVER="cvs.sourceforge.net:/cvsroot/beepmp"
ECVS_MODULE="bmp"
ECVS_TOP_DIR="${DISTDIR}/cvs-src/${ECVS_MODULE}"

DESCRIPTION="Beep Media Player"
HOMEPAGE="http://beepmp.sourceforge.net/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~sparc ~amd64"
IUSE="nls esd gnome oggvorbis alsa"

RDEPEND="app-arch/unzip
        >=x11-libs/gtk+-2.4
        >=x11-libs/pango-1.4
        >=dev-libs/libxml-1.8.17
        >=gnome-base/libglade-2.3
        esd? ( >=media-sound/esound-0.2.30 )
        gnome? ( >=gnome-base/gnome-2.6 )
        oggvorbis? ( >=media-libs/libvorbis-1.0 )
        alsa? ( >=media-libs/alsa-lib-1.0 )"
DEPEND="${RDEPEND}
        nls? ( dev-util/intltool )"
 
S=${WORKDIR}/${ECVS_MODULE}
 
src_compile() {
        local myconf=""
 
        export WANT_AUTOMAKE=1.7
        export WANT_AUTOCONF=2.5
 
        ./autogen.sh
 
        econf \
                --with-dev-dsp=/dev/sound/dsp \
                --with-dev-mixer=/dev/sound/mixer \
                `use_enable oggvorbis vorbis` \
                `use_enable esd` \
                `use_enable nls` \
                `use_enable alsa` \
                `use_enable gnome gconf` \
                `use_enable gnome gnomevfs` \
                ${myconf} \
                || die
 
        emake || die "make failed"
}
 
src_install() {
        einstall || die "install failed"
 
        insinto /usr/share/pixmaps
        doins beep/beep.svg
        doins beep/beep_mini.xpm
 
        # Get the app registered in gnome
 
        if use gnome; then
                insinto /usr/share/gnome/apps/Multimedia
                doins ${FILESDIR}/beep-media-player.desktop
        fi
 
        dodoc AUTHORS ChangeLog COPYING FAQ NEWS README TODO
}

beepmp-cvs-20040325.ebuild: questo invece usa l'ultimo snapshot "ufficiale" messo a disposizione dagli sviluppatori, lo uso da due mesi ed è assolutamente stabile (a meno di qualche difetto con plugin non testati, ad esempio musepack, che non può essere configurato)

beepmp-cvs-20040325.ebuild

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2

inherit eutils
 
MY_PN="bmp"
MY_P=${MY_PN}-cvs-${PV}
 
DESCRIPTION="Beep Media Player"
HOMEPAGE="http://beepmp.sourceforge.net/"
SRC_URI="mirror://sourceforge/beepmp/${MY_P}.tar.gz"
 
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="nls esd gnome oggvorbis alsa"
 
RDEPEND="app-arch/unzip
        >=x11-libs/gtk+-2.4
        >=x11-libs/pango-1.4
        >=dev-libs/libxml-1.8.17
        >=gnome-base/libglade-2.3
        esd? ( >=media-sound/esound-0.2.30 )
        gnome? ( >=gnome-base/gnome-2.6 )
        oggvorbis? ( >=media-libs/libvorbis-1.0 )
        alsa? ( >=media-libs/alsa-lib-1.0 )"
DEPEND="${RDEPEND}
        nls? ( dev-util/intltool )"
 
S=${WORKDIR}/${MY_PN}-0.9.7
 
src_compile() {
        local myconf=""
 
        econf \
                --with-dev-dsp=/dev/sound/dsp \
                --with-dev-mixer=/dev/sound/mixer \
                `use_enable oggvorbis vorbis` \
                `use_enable esd` \
                `use_enable nls` \
                `use_enable alsa` \
                `use_enable gnome gconf` \
                `use_enable gnome gnomevfs` \
                ${myconf} \
                || die
 
        emake || die "make failed"
}
 
src_install() {
        einstall || die "install failed"
 
        insinto /usr/share/pixmaps
        doins beep/beep.svg
        doins beep/beep_mini.xpm
 
        # Get the app registered in gnome
 
        if use gnome; then
                insinto /usr/share/gnome/apps/Multimedia
                doins ${FILESDIR}/beep-media-player.desktop
        fi
 
        dodoc AUTHORS ChangeLog COPYING FAQ NEWS README TODO
}

[Duncan]

Stasera se non son ad impazzire con cocoon lo provo

Grazie