[VB] Creazione programma per modifcare un file

[RunDLL]

Ciao a tutti e grazie per leggere la mia richiesta: sono alle prima armi con Visual Basic e mi trovo davanti alla necessità di creare un programma che dovrebbe fare le operazioni cui vado ad illustrare.
Utilizzo un programma che mi crea un file TXT dove vengono archiviati dei prodotti, in particolare due campi: 1 codice prodotto 2 quantità.
Il file ha il formato così: il campo codice sempre di 9 caratteri (se il codice è di meno caratteri aggiunge automaticamente tanti 0 fino a raggiungere 9 cifre), 4 spazi, un punto e virgola, la quantità sempre di 6 caratteri (stesso discorso dei 0 del codice) e un punto e virgola. Faccio un esempio, ammettiamo che ho il prodotto di codice 123 di cui ne ho 4 nel file troverò questa forma:

000000123 ;000004;

Ogni prodotto aggiunto verrà inserito nel file in una nuova riga, esempio per 3 prodotti:

000000123 ;000004;
000001345 ;000010;
000909874 ;000150;

Non c'è altro modo per impostare questo file che abbia un'altra forma, esce così e basta.
Ovviamente i prodotti potrebbero essera anche migliaia.
Io dovrei importare tale file in un'altro programma che accetta ESCLUSIVAMENTE un file che abbia 19 caratteri e codice e quantità uniti. Come vedete codice + quantità sono di 15 caratteri.
Per cui il programma che vorrei realizzare mi dovrebbe fare queste cose:
1) eliminare i quattro spazi + punto e virgola tra codice e quantità;
2) eliminare il punto e virgola in fondo alla riga;
3) aggiungere tanti zeri quanti caratteri mancano ad arrivare a 19 totali (in questo caso 4 zeri) tutti a sinistra ovvero davanti a codice;
4) crearmi un file con le modifiche apportate non che mi modifichi il file sorgente.

nel caso dell'esempio dei 3 prodotti io come risultato finale mi dovrei ritrovare un file così composto:

0000000000123000004
0000000001345000010
0000000909874000150

Non so se chiedo troppo ma siccome mi interesserebbe capire anche il meccanismo vorrei trovare una buon'anima che oltre a darmi il codice mi illustrerebbe in maniera particolareggiata le istruzioni perchè vorrei imparare. Ovviamente se non è troppo disturbo o troppo complicato. Un grazie a tutti e saluti.

[RunDLL]

Il forum non mi permette di mettere 4 spazi tra codice ed il primo punto e virgola negli esempi ma ci sono 4 spazi vuoti.

[cisky]

Ciao, questo è un esempio di codice che ho realizzato come spunto.
Ho commentato tutto e dovrebbe essere piuttosto chiaro.

NOTA: Per poter accedere alla libreria SCRIPTING, devi aggiungere nel progettoVB il riferimento alla libreria 'Microsoft Scripting Runtime'.
(In questo modo puoi usare una serie di oggetti che gestiscono comodamente la lettura e la scrittura dei file...)

Dal menù: Progetto -> Riferimenti

Ciao!

Private Sub Esempio()


    Dim oFileSystem         As Scripting.FileSystemObject
    Dim oInputFile          As Scripting.TextStream
    Dim oOutputFile         As Scripting.TextStream
    Dim sLineText           As String
    Dim sLineTextChanged    As String
        
    ' *** Come prima cosa, creo un'oggetto "FileSystemObject" che seve per gestire
    '     varie operazioni sui file.
    '
    Set oFileSystem = New Scripting.FileSystemObject
    
    ' *** Tramite l'oggetto "FileSystemObject" leggo il file originale (Quello con i codici da modificare)
    '     e tramite il metodo 'OpenTextFile' ottengo un oggetto di tipo "TextStream" che praticamente
    '     rappresenta il file in questione.
    '
    Set oInputFile = oFileSystem.OpenTextFile("C:\FileOriginale.txt", ForReading)
    
    ' *** Allo stesso modo, gestisco un TextStream per scrivere il file modificato...
    Set oOutputFile = oFileSystem.OpenTextFile("C:\FileModificato.txt", ForWriting, True)
        
    Do While Not oInputFile.AtEndOfStream       ' *** Scorro tutto il file originale
        
       ' *** Leggo il testo di una riga del file
       sLineText = oInputFile.ReadLine()
        
       ' *** Modifico il testo della riga del file originale
       sLineTextChanged = ChangeLineText(sLineText)
        
       ' *** Scrivo il testo corretto nel nuovo file (quello modificato)
       oOutputFile.WriteLine sLineTextChanged
    Loop

    ' *** Chiudo i file...
    oInputFile.Close
    oOutputFile.Close
    
End Sub

' Questa routine trasforma una riga con il testo  "000000123    ;000004;"
' Nel seguente formato:   "0000000000123000004"
'
Private Function ChangeLineText(ByVal sOriginalText As String) As String
        
    Dim sCodiceProdotto         As String
    Dim sQuantita               As String
    Dim iPos                    As Integer
    Dim sTextChanged            As String
    Dim lLen                    As Long

    ' *** Trovo la posizione del 1° ";" nella linea
    iPos = InStr(1, sOriginalText, ";", vbTextCompare)
    
    ' *** Il codice del prodotto è il testo che stà a sinistra rispetto alla posizione del ";"
    sCodiceProdotto = Left$(sOriginalText, iPos - 1)
    
    ' *** La quantità è il testo che stà a destra rispetto alla posizione del ";"
    sQuantita = Mid$(sOriginalText, iPos + 1)

    ' *** Rimuovo gli spazi iniziali e finali dal testo, tramite l'istruzione TRIM
    sCodiceProdotto = Trim(sCodiceProdotto)
    sQuantita = Trim(sQuantita)
    
    ' *** Rimuovo il secondo carattere ";" che segue il valore della quantità
    sQuantita = Left$(sQuantita, Len(sQuantita) - 1)
    
    ' *** A questo punto unisco il codice con la quantita
    sTextChanged = sCodiceProdotto & sQuantita

    ' *** Se il testo è minore di 19 caratteri, aggiungo gli "0" iniziali
    '
    lLen = Len(sTextChanged)
    If lLen < 19 Then
        sTextChanged = String(19 - lLen, "0") & sTextChanged
    End If
    
    ChangeLineText = sTextChanged       ' Valore di ritorno della funzione

End Function

[RunDLL]

Ciao e grazie per la risposta. Per favore mi diresti ora dove inserire il codice? Va bene in un commandbutton all'evento "Click"? Oppure va bene anche in un modulo sotto Sub Main()? Grazie e scusami ma sono proprio all'inizio. Ciao

[cisky]

Puoi mettere il codice dove vuoi, sia in un modulo che in una form.
Nei moduli in genere si inseriscono delle routine generiche che possono essere usate in varie parti del codice, per questo caso puoi tranquillamente richiamare la routine "Esempio" da un pulsante della form.

Private Sub Command1_Click()
    Esempio
End Sub

Ciao!