PDA

View Full Version : [VB6] Uso file .ini


Zagor HW
20-04-2005, 20:06
Mi potreste spiegare come posso gestire un file .ini (lettura,scrittura e modifica) nella mia applicazione?

Grazie Ciao!

leadergl
20-04-2005, 22:05
La cosa è semplice, devi:
1) dichiarare le api di windows che servono alla modifica/lettura dei file INI:

' -----------------------------------------------------------------
'Funzioni per la Gestione dei Files .INI delle Impostazioni
' -----------------------------------------------------------------
Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpString As Any, ByVal lpFileName As String) As Long
Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long

2) creare le funzioni di lettura e scrittura, ad esempio:

Public Function INIRead(File As String, Section As String, Item As String) As String
Dim sBuf As String
Dim iRC As Integer

sBuf = Space(1023)
iRC = GetPrivateProfileString(Section, Item, "Not Found", sBuf, 1023, App.Path + "/" + File)
sBuf = Left$(sBuf, iRC)

If StrComp(sBuf, "Not Found") = 0 Then
INIRead = vbNullString
Else
INIRead = sBuf
End If

End Function

Public Sub INIWrite(File As String, Section As String, Item As String, ItemValue As String)
WritePrivateProfileString Section, Item, ItemValue, App.Path + "/" + File
End Sub


queste cose dette puoi ad esempio metterle in un Modulo.

Successivamente dovrai solo richiamare una delle due funzioni per gestire il file INI, ad esempio:
LETTURA:
INIRead("nome_file.ini", Sezione , valore_da_leggere)

SCRITTURA:
INIWrite "nome_file.ini", Sezione, valore_da_Scrivere, valore

tutto qui ;)

Zagor HW
21-04-2005, 13:05
Ok il codice mi funziona perfettamente!Ma quei 2 lunghi blocchi di codice sono sempre uguali per qualsiasi progetto vero?E cosi per curiosità, di preciso in questa porzione di codice della lettura:

sBuf = Space(1023)
iRC = GetPrivateProfileString(Section, Item, "Not Found", sBuf, 1023, App.Path + "/" + File)
sBuf = Left$(sBuf, iRC)

If StrComp(sBuf, "Not Found") = 0 Then
INIRead = vbNullString
Else
INIRead = sBuf
End If

Cosa fa di preciso?

Grazie ciao!

salvuccio
21-04-2005, 13:27
....
E cosi per curiosità, di preciso in questa porzione di codice della lettura:



sBuf = Space(1023)

riempie la variabile sBuf di spazi (1023)


iRC = GetPrivateProfileString(Section, Item, "Not Found", sBuf, 1023, App.Path + "/" + File)

ottiene nella variabile iRC il numero di caratteri restituiti dalla funzione nella variabile sBuf


sBuf = Left$(sBuf, iRC)


ridimensiona sBuf


If StrComp(sBuf, "Not Found") = 0 Then
INIRead = vbNullString
Else
INIRead = sBuf
End If



se il contenuto di sBuf è = a "Not Found" restituisce il valore vbNullString
altrimenti il contenuto di sBuf

Massi91
21-04-2005, 13:59
scusate, ma come funziona?

per esempio, il contenuto di un file ini è:

[Color]
Button=30,50,50


e il codice per leggere il valore sarà:


MsgBox INIRead("C:\I.ini", "Color", "V")


ma perchè non esce niente???

salvuccio
21-04-2005, 14:08
scusate, ma come funziona?

per esempio, il contenuto di un file ini è:

[Color]
Button=30,50,50


e il codice per leggere il valore sarà:


MsgBox INIRead("C:\I.ini", "Color", "V")


ma perchè non esce niente???

se non ricordo male ogni chiave può avere un solo valore quindi dovresti avere qualcosa del tipo:
Button=30
Button1=50
Button2=50

e richiamare quindi

MsgBox INIRead("C:\I.ini", "Color", "Button")

MsgBox INIRead("C:\I.ini", "Color", "Button1")

MsgBox INIRead("C:\I.ini", "Color", "Button2")

leadergl
21-04-2005, 14:11
non esce niente perchè il valore "V" non esiste.

dovresti fare:
MsgBox INIREAD("C:\I.ini","Color","Button")
ed allora avrai come risultato:
"30,50,50"

Massi91
21-04-2005, 14:13
nell'ini ("C:\I.ini")...

[Color]
Button=30
Button1=50
Button2=50

e nel codice...

MsgBox INIRead("C:\I.ini", "Color", "Button")
MsgBox INIRead("C:\I.ini", "Color", "Button1")
MsgBox INIRead("C:\I.ini", "Color", "Button2")


e niente... la solita stringa vuota... scusate per prima, avevo fatto una prova con l'ini e avevo messo v e mi ero scordato di aggiornare il codice...

dove ho sbagliato???? :muro: :muro: :cry:

Zagor HW
21-04-2005, 14:41
Ok, grazie ancora x l'aiuto, ma avrei un'ultima domanda... come faccio a cancellare una sezione intera oppure un oggetto intero?

Grazie ciao!

Massi91
21-04-2005, 14:42
Ah ho trovato!


iRC = GetPrivateProfileString(Section, Item, "Not Found", sBuf, 1023, App.Path + "/" + File)


quindi si dovrà indicare solo il nome del file e non tutto il percorso! Vero? :D

giusto!

salvuccio
21-04-2005, 14:57
Ah ho trovato!


iRC = GetPrivateProfileString(Section, Item, "Not Found", sBuf, 1023, App.Path + "/" + File)


quindi si dovrà indicare solo il nome del file e non tutto il percorso! Vero? :D

giusto!

azz, non ci avevo fatto caso, ma qui presuppone che il file si trovi nella stessa cartella dell'applicazione, quindi credo che utilizzandolo così ti crea un nuovo file vuoto ed è normale che non ti ritorni nulla.
Volendo fornire un percorso completo credo che basti togliere App.Path + "/" +.
Non sono poi sicuro se debba essere scritto "/" e non piuttosto "\".

PS: Non fucilatemi, sono all'inizio con VB.

Massi91
21-04-2005, 15:35
azz, non ci avevo fatto caso, ma qui presuppone che il file si trovi nella stessa cartella dell'applicazione, quindi credo che utilizzandolo così ti crea un nuovo file vuoto ed è normale che non ti ritorni nulla.
Volendo fornire un percorso completo credo che basti togliere App.Path + "/" +.
Non sono poi sicuro se debba essere scritto "/" e non piuttosto "\".

PS: Non fucilatemi, sono all'inizio con VB.


non ti preoccupare, è giusto! infatti ho tolto quel pezzetto di codice... cmq nelle path (almeno per quello che so) "/" e "\" sono indifferenti...
grazie lo stesso a tutti!

salvuccio
21-04-2005, 16:46
Ok, grazie ancora x l'aiuto, ma avrei un'ultima domanda... come faccio a cancellare una sezione intera oppure un oggetto intero?

Grazie ciao!

Spero di non aver scopiazzato male :p .

Per cancellare una chiave nel file .ini:


Public Sub CancellaIniKey(Nomesezione As String, NomeKey As String, NomeIniFile As String)
Call WritePrivateProfileString(Nomesezione, NomeKey, vbNullString, NomeIniFile)
End Sub


Per cancellare una intera sezione nel file .ini:


Public Sub CancellaSezioneIni(Nomesezione As String, NomeIniFile As String)
Call WritePrivateProfileString(Nomesezione, vbNullString, vbNullString, NomeIniFile)
End Sub


se poi vuoi cancellare l'intero file .ini


Kill percorsocompletodelfile.ini

Zagor HW
21-04-2005, 17:17
Ok...

Grazie ancora x l'aiuto! Ciao!